分析的话我们就不多说了，下面直接看示例程序如何来实现这个功能。
首先建立一个项目，拖放一个TreeView 控件于窗体上，然后为TreeView 控件添加类似下图一所示的树状结构：
图一：示例的窗体
先建立一个检查某个节点的所有子节点的递归过程，通过它我们遍历所有的子节点，同时根据父节点的状态改变它们的复选框状态，代码如下：
Private Sub CheckAllChildNodes(ByVal treeNode As TreeNode, ByVal nodeChecked As Boolean)
Dim node As TreeNode
For Each node In treeNode.Nodes
node.Checked = nodeChecked
If node.Nodes.Count > 0 Then
Me.CheckAllChildNodes(node, nodeChecked)
End If
Next node
End Sub
同时我们也想根据某个节点的状态改变来影响其所有上层的父节点的状态。例如，一个第三层的节点复选框状态从选中变为非选中，如果第三层其它的节点的复选框都是非选中状态，就让它们的父节点(第二层的某个节点)状态改变为非选中，依次类推到最顶级的根节点。要实现这样的功能，我们也需要通过一个递归过程来判断，判断依据为：当一个节点Node的复选框状态改变时，我们就遍历它父节点的Nodes(该集合包含了Node)集合，对比Nodes中是不是所有节点都和Node的状态相同，如果所有节点都为非选中的状态，则父节点变为非选中状态，否则为选中状态。详细代码如下：
'检查所有的本层节点，如果所有节点都选中，则父节点也选中，如果所有节点非选中，则父节点也不选中
Private Sub CheckAllFatherNodes(ByVal treeNode As TreeNode, ByVal nodeChecked As Boolean)
Dim node As TreeNode
Dim isSame As Boolean = True '记下nodeChecked的状态
If Not treeNode.Parent Is Nothing Then
For Each node In treeNode.Parent.Nodes
'碰到与nodeChecked状态不一样的节点
If node.Checked <> nodeChecked Then
isSame = False
Exit For
End If
Next
If isSame = False Then
'当所有节点中有一个不一样的节点时，肯定存在一个是选中的节点，所以父节点为选中
treeNode.Parent.Checked = True
Else
'当所有节点的状态都一样时，父节点状态等于节点状态
treeNode.Parent.Checked = nodeChecked
End If
CheckAllFatherNodes(treeNode.Parent, treeNode.Parent.Checked)
End If
node = Nothing
End Sub
然后在TreeView 控件的 AfterCheck 事件中添加如下代码：
Private Sub TreeView1_AfterCheck(ByVal sender As Object, ByVal e As System.Windows.Forms.TreeViewEventArgs) Handles TreeView1.AfterCheck
If e.Action <> TreeViewAction.Unknown Then
If e.Node.Nodes.Count > 0 Then
Me.CheckAllChildNodes(e.Node, e.Node.Checked)
End If
CheckAllFatherNodes(e.Node, e.Node.Checked)
Debug.WriteLine(e.Node.Text)
End If
End Sub
注意，因为每个节点复选框的状态改变后都会引发 AfterCheck 事件，我们为了避免无限次地进入递归中，就需要判断TreeViewAction的状态，所有被我们使用代码自动选中的节点的TreeViewAction 状态为 Unknown，因为可以避免我们调用递归过程的时候出问题。
http://www.qqrea
d.com/book/myvbnet/my0051.html
代码编写完毕，现在我们运行程序，单击改变节点的状态，观察下它的子节点和父节点的复选框状态的变化，如下两个图为其中的两种情况：
图二：示例运行效果图
图三：示例运行效果图
最新报道 
